Excel VBA - Create a new worksheet

It may seem trivial, but even the smallest things have to be handled carefully when programming.

Therefore I have some standard functions, which handle the creation of new worksheets in my VBA projects. So far I never had trouble with them plus they emphazise NOT to use existing worksheets for your coding. Instead it is better to always create new worksheets. This way you have full control over your programm.

If you start coupling Excel files with source code, you start a war that you cannot win. If your source code relies on a certain status in Excel files, it will fail by time and you spend a lot of time handling errors, which can easily be avoided.

However, here the source code for creating a new worksheet safely.

' @Author - Alexander Bolte
' @ChangeDate - 2014-05-31
' @Description - checks, if a worksheet exists under given name in given workbook.
' @Param myBook - an initialized Excel Workbook, which should be searched for given sheet name.
' @Param sheetName - a String holding the sheets name, which should be searched in given workbook.
' @Returns true, if the sheet exists, else false.
Public Function worksheetExists(ByRef myBook As Workbook, ByVal sheetName As String) As Boolean
    Dim ret As Boolean
    Dim tmpS As Worksheet
    
On Error GoTo errHandler:
    Set tmpS = myBook.Worksheets(sheetName)
    ret = True
    Set tmpS = Nothing
    
errHandler:
    If Err.Number <> 0 Then
        ret = False
        Err.Clear
    End If
    
    worksheetExists = ret
End Function


' @Author - Alexander Bolte
' @ChangeDate - 2014-05-31
' @Description - creates a new worksheet with given name in given workbook. If a worksheet already exists under given name, it is deleted and replaced with an empty worksheet.
' @Param myBook - an initialized Excel Workbook, which should be searched for given sheet name.
' @Param sheetName - a String holding the sheets name, which should be created in given workbook.
' @Returns a Worksheet object referencing a newly created worksheet in given workbook.
Public Function createWorksheet(ByRef myBook As Workbook, ByVal sheetName As String) As Worksheet
    Dim tmpS As Worksheet
    
    ' ### delete the worksheet, if already existing ###
    If worksheetExists(myBook, sheetName) Then
        myBook.Worksheets(sheetName).Delete
    End If
    ' ### add a new worksheet ###
    Set tmpS = myBook.Worksheets.Add
    tmpS.Name = sheetName
    tmpS.Move myBook.Worksheets(1)
    
    Set createWorksheet = tmpS
End Function

If you do not want Excel to display warning Messages, you can switch them off using the DsiplayAlerts property of the Application object.

' Disable all alerts.
Application.DisplayAlerts = False
Hits: 4450