' @Author - Alexander Bolte
' @ChangeDate - 2014-10-21
' @Description - Returning a files name from a given file path.
' @Param filePath - a String providing a full path to one file.
' @Returns - a String holding a files name, if file exists and is accessible. Else an empty String is returned.
Public Function getFileNameFromFilePath(ByVal filePath As String) As String
    Dim fileName As String
    Dim fso As New scripting.FileSystemObject
    Dim f As scripting.File
    
    On Error GoTo errHandle:
    
    If fso.fileExists(filePath) Then
        Set f = fso.GetFile(filePath)
        fileName = f.Name
    End If
    Set f = Nothing
    Set fso = Nothing
    
errHandle:
    If Err.Number <> 0 Then
        Err.Clear
    End If
    
    getFileNameFromFilePath = fileName
End Function

' @Author - Alexander Bolte
' @ChangeDate - 2014-10-08
' @Description - Deleting a worksheet named like sheetName from given target Workbook, if a worksheet under given sheetName exists.
' @Param trg - an initialized workbook object.
' @Param sheetName - a String holding a unique worksheet name.
Public Function deleteWorksheet(ByRef trg As Workbook, ByVal sheetName As String)
    If worksheetExists(trg, sheetName) Then
        Call trg.Worksheets(sheetName).Delete
    End If
End Function